vlookup函数如何多条件查询（vlookup函数七大经典查询操作）

Excel处理日常工作的时候，99%的人都会碰到一个操作的那就是数据查询。说到数据查找都离不开一个函数，那就是vlookup函数，这个函数可以说的上是Excel函数中的NO.1。今天我们就来学习一下vlookup函数的七个经典查询操作。

操作一：vlookup函数简单查询

案例说明：根据姓名赵宇查询对应的工龄

函数公式：=VLOOKUP(G5,A:E,5,0)

函数说明：

vlookup函数作为查询函数，它的参数主要有4个参数，默认查询为向右查询。如下说明：

1、第一参数G5代表的是需要查询的值；第二参数A:E代表的是你需要查询的数据区域；第三参数5，代表你要要查询的数据在查询值右边的第几列；第四参数0代表精确查找，1代表模糊查找。

操作二：vlookup函数数据向左查询

案例说明：根据人员工号，向左查询出对应的姓名

函数公式：

=VLOOKUP(G5,IF({1,0},B1:B7,A1:A7),2,0)

函数说明：

vlookup函数向左查询的时候，需要搭配if函数进行协同处理。

1、if函数在这里的作用主要作为第二参数来使用。if函数的第一参数用{1，0}做一次数据判断，从而形成新的二维数据区域。我们选中IF函数按F9可以解析如下图：

2、如上IF函我们可以形成新的数据区域，当我们查询到对应的第一参数工号之后，就可以通过向右查询2位，找到对应的姓名。

操作三：vlookup Column组合函数批量查询数据

案例说明：利用column函数，根据姓名批量查询出对应的工号、部门、性别、工龄等

函数公式：

=VLOOKUP($G5,$A$1:$E$7,COLUMN(B1),0)

函数说明：

1、我们这里利用column函数来作为vlookup函数的第三参数，它的作用是返回当前值所在的列；

2、我们第三参数选择B1单元格，返回的值为2。当我们向右拖动时会得到C1\D1\E1等，分别返回的值为3、4、5。这样可以自动变化第三参数查询数据。

操作四：vlookup函数对不连续单元格数据进行查询

案例说明：我们需要在不影响之前填写数据的情况下，利用vlookup函数对空白单元格中根据姓名找到对应的工号和部门。

函数公式：=VLOOKUP(B3,H2:J19,2,0)

函数说明：

1、查询工号，首先选择C3:C10区域按Ctrl g，定位单元格选择空格，这样就选择了全部空白单元格。

2、输入上面的函数内容后，按Ctrl Enter快捷键结束，这样就可以空白单元格区域数据进行批量填充。查询部门也是同理。

操作五：vlookup函数如何替换查找的错误值

案例说明：当我们原始数据中没有对应的人时，查询不到的时候结果会显示为错误值#N/A。

函数公式：

=IFerror(VLOOKUP(E4,$B$2:$C$10,2,0),"")

函数说明：

1、当我们输入vlookup函数查询张强时，因为查不到人名所以会出现错误值；

2、IFerror函数为替换函数，当出现错误值时执行第二参数。

操作六：vlookup函数实现多条件查询

案例说明：我们需要根据日期和单号查询出对应的入库数量和入库型号。

函数公式：

{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,C:C),2,0)}

{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,D:D),2,0)}

函数说明：

1、vlookup函数进行多条件查询的时候，需要用到&符号和IF函数搭配使用；

2、第一参数用&符号就是将日期和单号连接组成一个统一的条件值，if函数的作用在于重组一个新的数据查询区域。

操作七：vlookup函数搭配通配符进行查询

案例说明：通过通配符？查询对应的王红、王红小两位和三位名字的工号。

函数公式：

=VLOOKUP("王"&"?",$A$1:$B$7,2,0)

=VLOOKUP("王"&"??",$A$1:$B$7,2,0)

函数说明：

1、通配符？代表的是任意一个字符，王？代表的就是姓氏为王，名一个字总共两个字的王姓工号。

现在你学会如何使用vlookup函数了吗？

,