怎么才算精通office（都不好意思说精通Office）

俗话说得好，Excel用得好，下班会很早，工作中最常用到的工具就是Excel，如何利用它提高自己的效率？今天先来分享一下Vlookup的几个常规操作方法：

Vlookup被称为Excel中的效率之王，但是大部分的Excel使用者都不能很好使用Vlookup。但是，VLOOKUP函数又是Excel中的大众情人。有平台曾经做过“如果只能选择学习Excel中的一项功能，你会选择哪个”的调查，Vlookup函数竟然高居第二位。

VLOOKUP的常规操作方法：

1、日期查找

在查找日期的时候查找的结果通常会是一串数字，为了使日期能够返回相应的格式，那么需要配合TEXT函数才能完成查找需求。

在F3单元格中输入公式=TEXT(VLOOKUP(E3,$A$2:$C$9,2,0),"yyyy/m/d")，按Enter键完成。如下图所示：

注：如返回格式为2018/12/03，则TEXT的第二个参数的格式可以设置为“yyyy/mm/dd”即可。

2、常规查找

查找姓名对应的销售额。在F3单元格中输入公式=VLOOKUP(E3,$A$2:$C$9,3,0)，按Enter键完成。如下图所示：

3、查找的值为空时

在当查找的值为空时，通常情况下会返回结果为0，那么如果让结果返回空白呢，解决的方法就是在公式后面一个“”。

在F3单元格中输入公式=VLOOKUP(E3,$A$2:$C$9,3,0)&""，按Enter键完成。如下图所示：

4、当查找的目标格式不统一时报错如何解决

（1）如果查找的目标值是文本格式，而数据区域中是数值格式。

如下图所示，A列中的员工编号为数值格式，而F3单元格中的员工编号为文本格式。

在G3单元格中输入公式：=VLOOKUP(--F3,$A$2:$D$9,4,0)，按Enter键完成。

注：--为两个负号，即减负的意思，可以理解为负负得正，这里是把文本强制转换为数值，所以问题就很容易被解决了。

（2）如果查找的目标值是数值格式，而数据区域中是文本格式。

如下图所示，A列中的员工编号为文本格式，而F3单元格中的员工编号为数值格式。

在G3单元格中输入公式：=VLOOKUP(F3&"",$A$2:$D$9,4,0)，按Enter键完成。

注：&""是强制地把数值格式转换成文本格式。

5、模糊查找

VLOOKUP函数也是支持模糊查找，即支持通配符查找。

查找姓名中带有“冰”字的员工的销售额，在H3单元格中输入公式：

=VLOOKUP("*"&G3&"*",$B$2:$D$9,3,0)，按Enter键完成。

注：如果要查找以“冰”开头的那么公式的第一参数为："*"&G3; 如果查找以“冰”结尾那么公式的第一个参数为：G3&"*"。

6、反向查找

VLOOKUP函数也可以进行反向查找。

在H2单元格中输入公式：{=VLOOKUP(G2,IF({1,0},$B$2:$B$9,$A$2:$A$9),2,0)}，按组合键<Ctrl Shift Enter>键完成后向下填充。

注：公式两边的花括号不是手动输入的，而是按组合键后自动输入的。

7、查找顺序与数据区域中顺序一致的多项

VLOOKUP函数查找顺序一致的多项时，可以借助COLUMN函数构建查找序列。

在H2单元格中输入公式：=VLOOKUP($G2,$A$2:$D$9,COLUMN(B1),0)，按Enter键后向右填充。

注：COLUMN函数是返回列号。第一个参数一定要锁定列号，这样才能正确的结果。

8、区域查找

有时候需要查找某一个值处于那个区间里。比如查找下列的销售额对应的销售提点为多少。在E2单元格中输入公式：=VLOOKUP(D2,$H$2:$I$8,2,1)，按Enter键完成。

注：这里使用该函数最后一个参数为1，即模糊查找，来确定查找的值处于给定的那一个区间。

9、十字交叉查询

VLOOKUP函数如果有两个条件是呈现十字交叉时且顺序与数据区域中的顺序不一致时，可以与MATCH函数完成查询。

在H2单元格中输入公式：=VLOOKUP($G2,$A$2:$D$9,MATCH(H$1,$A$1:$D$1,0),0)，按Enter键完成后向下向右填充。

注：一定要锁定VLOOKUP函数的第一个参数的列号，MATCH函数的第一个参数的行号，这样才能得到正确的结果。

10、多条件查询

VLOOKUP还能进行多条件查询，这个用法相信有很多人不知道吧。

在I2单元格中输入公式：

{=VLOOKUP(G2&H2,IF({1,0},$A$2:$A$9&$B$2:$B$9,$D$2:$D$9),2,0)}

按组合键<Ctrl Shift Enter>完成后向下填充。

注：公式两边的花括号不是手动输入的，而是按组合键后自动输入的。VLOOKUP的第三个参数为2，第四个参数为0是固定的。

11、一对多查询

VLOOKUP函数还能进行一对多查询，但是这个方法并不鼓励大家去使用。

在H2单元格中输入公式：

{=VLOOKUP($G$2&ROW(A1),IF({1,0},$A$2:$A$9&COUNTIF(INDIRECT("a2:a"&ROW($2:$9)),$G$2),$D$2:$D$9),2,0)}，按组合键<Ctrl Shift Enter>完向下填充。

注：公式两边的花括号不是手动输入的，而是按组合键后自动输入的。

,