如何制作批量下拉列表（制作多级下拉列表）

私信回复关键词【UP】~

立即获取VLOOKUP函数用法教程合集，一看就会！

老师，请问这个多级下拉列表怎么做？

要明白这个效果怎么做，你必须清楚下面这几点，这是 Excel 必备的基础。

第一，如何制作下拉列表？下拉列表的本质是什么？

第二，如何给每个单元格制作对应的下拉选项？

注意看，当「产品线」变化时，H 列的「大类」选项是动态变化的。

类似的，选择「大类」的时候，I 列的「中类」也是随之更新的。

因为单元格数据是根据条件更新的，所以对应创建的下拉列表，也是动态变化的。

所以，我们需要做的，就是给每一个单元格，设置一个对应的动态下拉选项。

接下来是具体的解决方法。

01解决方法

这个效果使用 FILTER 和 UNIQUE 函数可以轻松实现（PS：此函数适用于 Office 365）。

先准备好对应类别的明细。

我们挨个看一下每个类别下拉列表的做法。

▋产品线下拉列表

首先针对「产品」使用 UNIQUE 函数，提取 B 列的非重复值。

公式如下：

=UNIQUE(B3:B32)

然后，选中 G3 单元格，在上方选项卡中，找到【数据验证】；

验证条件中，设置「允许」为「序列」；

「来源」为「=$G$7#」，点击确定：

这样产品线的下拉列表就搞定啦！

▋大类下拉列表

产品的「大类」是需要根据「产品线」内容动态更新的。

比如选择食品，那么就要把食品对应的大类提取出来。

这里可以分成两个步骤。

❶ 筛选「食品」对应的「大类」。

这个简单，用 FILTER 函数就可以实现。（FILTER 函数目前仅适用于 Office 365 预览体验计划~）

语法如下：

=FILTER(要筛选的数据列,筛选条件,无法满足条件时返回的值)

公式如下：

=FILTER(C3:C32,B3:B32=G3)

❷ 对「大类」内容提取唯一值。

这个是 UNIQUE 函数要干的活，在上一步的公式基础上，套一个 UNIQUE 函数就可以了。

公式如下：

=UNIQUE(FILTER(C3:C32,B3:B32=G3))

下拉列表的创建，和「产品线」完全一样，就不再重复演示了~

▋中类下拉列表

接下来提取「中类」的内容，思路和提取「大类」是一样的。

❶ 筛选对应「中类」的内容。

首先找出大类对应的中类所有内容。这里使用 FILTER 来实现。

公式如下：

=FILTER(D3:D32,C3:C32=H3)

❷ 提取「中类」唯一值。

然后使用 UNIQUE 函数对内容提取唯一值。

公式和「大类」基本一样：

=UNIQUE(FILTER(D3:D32,C3:C32=H3))

▋明细下拉列表

接下来的「明细」也是相同的思路，公式如下：

=UNIQUE(FILTER(E3:E32,D3:D32=I3))

02总结

我们再来总结一下。

❶ 多级下拉列表的本质是，给每个单元格设定对应的下拉选项。

❷ 如何设置动态的下拉选项？

使用 FILTER 函数，有条件地筛选下拉选项，然后用 UNIQUE 函数提取唯一值。

因为单元格内容是动态的，那么下拉选项肯定也是动态的。

明白了这个原理之后，我们还可以做出很多其他的效果！

比如按照关键字进行模糊匹配，再输出对应的下拉列表选项。

对应的公式是：

=FILTER(A2:A15,ISNUMBER(FIND(C2,A2:A15)))

最后，考一考你：

你能够用文字解释一下这段公式的作用和原理吗？

评论区等你的答案！

私信回复关键词【UP】~

立即获取VLOOKUP函数用法教程合集，一看就会！

,