会计对账单怎么快速核对（一招搞定库存汇总）

小伙伴们好啊~

不知道小主们是否遇到过这种事：一个简单的关键词回复，居然错了一两千人，本来可以自动回复，却演变成手工复制粘贴，浪费了不必要的时间...

所以呀，本周为各位带来两个表格操作技巧：一招搞定库存汇总&会计对账不加班的秘密，加班什么的根本不存在。

小主们，心动吗？

赶紧收藏看起来~

一、一招搞定库存汇总

库存表这个大部分公司都会用到，只是形式不同而已。今天，为小主们讲解一下库存表。

1.明细表

每个地区的库存表格式一样，第2行为汇总数据，第4行为工厂。第2行本来是没有公式的，卢子这里增加一条公式，方便统计。在B2输入公式，向右拖动。

=SUM(B5:B998)

2.汇总表

根据明细表，将每个地区每个工厂的数量进行汇总。

正常查找引用都是用VLOOKUP函数，不过这里的明细表格式不支持，查找区域在明细表第4行，返回区域在明细表第2行。

其实，VLOOKUP函数有一个超级牛逼的兄弟，叫LOOKUP函数。这个函数360°无死角，通通可以查找。记住这个函数的语法：

=LOOKUP(1,0/(查找值=查找区域),返回区域)

现在要统计华北区，直接套用公式即可，在汇总表B3输入公式，向右拖动。

=LOOKUP(1,0/(B2=华北区!4:4),华北区!2:2)

同理，东北区可以用公式：

=LOOKUP(1,0/(B2=东北区!4:4),东北区!2:2)

这里只是列举了5个地区，每个地区改一次公式也挺方便的。

现在问题来了，全国可以划分成好多个地区，如果都这样改显得超级繁琐，而且容易出错，怎么办呢？？

可以这样做：

刚好每个地区都列在A列，这样其实就间接给我们提供了地区的名称，可以进行引用。这里借助&将工作表名称跟区域连接起来。

=A3&"!4:4"

不过用&连接起来的只能算文本，并不是真正的区域，需要嵌套INDIRECT函数才可以真正变成区域。再将刚刚的公式组合起来就基本搞定，还剩下最后一点点细节。

=LOOKUP(1,0/(INDIRECT(A3&"!4:4")=B2),INDIRECT(A3&"!2:2"))

我们在使用公式的时候，需要下拉和右拉，这时该固定的区域别忘了加$，要不然就会出错。

=LOOKUP(1,0/(INDIRECT($A3&"!4:4")=B$2),INDIRECT($A3&"!2:2"))

当然，这里可以将公式写得更加完美，实际上每个地区的工厂可能不一样，就会导致一些工厂没有对应值导致出错，比如现在将其中一个工厂改成潮州工厂。

查找不到对应值会显示错误值，只需再嵌套一个IFERROR函数，即可解决这个问题。

=IFERROR(LOOKUP(1,0/(INDIRECT($A3&"!4:4")=B$2),INDIRECT($A3&"!2:2")),0)

合计就直接用SUM函数就行。

行合计：

=SUM(B3:B7)

列合计：

=SUM(B3:H3)

在写公式的时候，一定要将公式从最基础的开始写，然后一步步改进。千万别想着一步到位，除非你本身就是高手啦~

二、Excel对账不加班的真相

1.对账

会计科目为：谢谢你！，你的会计科目却是五花八门，看起来一样，实际却不同。微信认为不同，Excel也认为不同，只有人工才认为一样。两边的会计科目不一样，用Excel如何对账？

没法，直接手工一个个审核，这样不加班才怪。标准化才能提高工作效率，告别加班！

会计科目一样，在微信是智能回复，在Excel一个VLOOKUP函数也能轻松解决，多么省事。

=VLOOKUP(D2,A:B,2,0)

用汉字容易出错，可以使用唯一性的科目代码，用数字出错率就会降低。

=VLOOKUP(E2,A:C,3,0)

数字也会出错，就是两边格式不同，一边为文本格式，一边为数值格式。不过面对格式不同，对公式略作改变即可解决。

Step 01 左边是文本格式，右边是数值格式，可以通过&""解决。

=VLOOKUP(E2&"",A:C,3,0)

Step 02 左边是数值格式，右边是文本格式，可以通过--解决。

=VLOOKUP(--E2,A:C,3,0)

2.金额分摊

根据分摊开始月、分摊结束月，将付款金额平均分摊到每个月。

举个例子，分摊开始月为2017/07，在这个日期之前就不能有分摊金额，分摊结束月为2018/06，在这个日期之后就不能有分摊金额。根据这个条件，可以这样设置：

=IF(OR($A2>E$1,E$1>$B2),"",分摊金额)

分摊金额就是付款金额除以分摊的总月份，算两个日期的间隔月份可以用DATEDIF函数。

=DATEDIF($A2,$B2,"m") 1

分摊金额：

=$D2/(DATEDIF($A2,$B2,"m") 1)

好，现在将公式组合起来就是最终结果。

=IF(OR($A2>E$1,E$1>$B2),"",$D2/(DATEDIF($A2,$B2,"m") 1))

切记：将公式从最基础的开始写，然后一步步改进~

从此会计对账经常加班的现象不会再找你。

在这里相信有许多想要学习会计的同学，大家可以关注小编头条号，私信【学习】即可免费领取一整套系统的会计学习教程！

,